%ffp

// RGB -> Hex converter

Category: "FilterMeister"
Title: "RGB-Hex Converter"
Author: "Werner D.Streidt, Alex Hunter, Alfredo Mateus"
Copyright: "© 1999"
Filename: "FM_Hex2RGB.8bf"
Version: "1.0"

Dialog: Color=LightGray

ctl[0]: RADIOBUTTON(GROUP), "Select color from image", Pos=(170,10), Val=1, Action=PREVIEW
ctl[1]: RADIOBUTTON, "Compute custom RGB value", Size=(110,*), Pos=(275,10), Action=PREVIEW

ctl[2]: "", Pos=(230,30), Val=50
ctl[3]: "", Pos=(230,41), Val=50
ctl[4]: "", Pos=(230,52)

ctl[5]: COMBOBOX(DROPDOWN), Pos=(270,80), Size=(50,*), Tooltip="Select text and right-click to copy to copyboard"
ctl[6]: OWNERDRAW(BORDER), Pos=(230,72), Size=(30,30)


ForEveryTile:
{

if (ctl(0))
{
	enableCtl(4,0);
	setCtlText(2, "x-pos (%)");
	setCtlRange(2,0,100);

	setCtlText(3, "y-pos (%)");
	setCtlRange(3,0,100);

	setCtlTextv(5, "#%02X%02X%02X",src(ctl(2)*X/100,ctl(3)*Y/100,0),
	src(ctl(2)*X/100,ctl(3)*Y/100,1),
	src(ctl(2)*X/100,ctl(3)*Y/100,2));
	setCtlVal(5,0); // force entry 0 to be loaded into edit field

	for (x=0; x<X; x++)
		pset(x,ctl(3)*Y/100,0, 255);

	for (y=0; y<Y; y++)
		pset(ctl(2)*X/100,y,0, 255);

	setCtlColor(6,RGB(src(ctl(2)*X/100,ctl(3)*Y/100,0),
	src(ctl(2)*X/100,ctl(3)*Y/100,1),src(ctl(2)*X/100,
	ctl(3)*Y/100,2)) );
}
else 
{
	enableCtl(4,-1);
	setCtlTextv(2, "Red: %02X", ctl(2));
	setCtlRange(2,0,255);

	setCtlTextv(3, "Green: %02X", ctl(3));
	setCtlRange(3,0,255);

	setCtlTextv(4, "Blue: %02X", ctl(4));

	setCtlTextv(5, "#%02X%02X%02X",ctl(2), ctl(3), ctl(4));
	setCtlVal(5,0); // force entry 0 to be loaded into edit field

	setCtlColor(6,RGB(ctl(2), ctl(3), ctl(4)) );
}

if (doingProxy)
	return true;
else
	return false;
}